From ad70a6505bb3f052c6a0161ae0d2010c654737b3 Mon Sep 17 00:00:00 2001
From: Caroline Larimore <caroline@larimo.re>
Date: Sat, 20 Jul 2024 17:50:59 -0700
Subject: Rework web roles

---
 roles/web/personal/default.nix | 56 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 roles/web/personal/default.nix

(limited to 'roles/web/personal/default.nix')

diff --git a/roles/web/personal/default.nix b/roles/web/personal/default.nix
new file mode 100644
index 0000000..e036f98
--- /dev/null
+++ b/roles/web/personal/default.nix
@@ -0,0 +1,56 @@
+{ config, pkgs, lib, inputs, ... }:
+with lib;
+
+let 
+  cfg = config.roles.web.personal;
+  package = (pkgs.buildGoModule rec {
+    pname = "site";
+    version = "6612d84c63a7bbc2a5b70607f2ec32ea070c4659";
+
+    src = pkgs.fetchFromGitHub {
+      owner = "CartConnoisseur";
+      repo = "site";
+      rev = "${version}";
+      hash = "sha256-n54+LdtMyjoLfaFqd7tcDQqBiYCdUW/Rs67Vc4QwEJ0=";
+    };
+
+    # kinda a hack, but whatever
+    postBuild = ''
+      mkdir -p $out/share/site
+      cp -r $src/* $out/share/site/
+    '';
+
+    vendorHash = "sha256-2/4Wv7nsaT0wnUzkRgHKpSswigDj9nOvlmYXK29rvLU=";
+  });
+in {
+  options.roles.web.personal = {
+    enable = mkEnableOption "personal site";
+  };
+
+  config = mkIf cfg.enable {
+    networking.firewall.allowedTCPPorts = [ 80 ];
+    
+    services.nginx = {
+      enable = true;
+      virtualHosts = {
+        "caroline.larimo.re" = {
+          serverAliases = [ "cxl.sh" "localhost" ];
+          locations."/" = {
+            recommendedProxySettings = true;
+            proxyPass = "http://localhost:8080/";
+          };
+        };
+      };
+    };
+
+    systemd.services."web.personal" = {
+      enable = true;
+      wantedBy = [ "multi-user.target" ];
+
+      serviceConfig = {
+        WorkingDirectory = "${package}/share/site";
+        ExecStart = "${package}/bin/site";
+      };
+    };
+  };
+}
-- 
cgit v1.2.3