modules/nixos/system/fonts/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

{ options, config, lib, pkgs, namespace, ... }:

with lib; with lib.${namespace}; let
  cfg = config.${namespace}.system.fonts;
in {
  options.${namespace}.system.fonts = with types; {
    enable = mkEnableOption "fonts";
    nerdfonts = mkEnableOption "nerdfonts";
    extra = mkOption {
      type = listOf package;
      default = [];
      description = ''
        additional fonts to install
      '';
    };
  };

  config = mkIf cfg.enable {
    fonts = {
      packages = with pkgs; [
        noto-fonts
        noto-fonts-cjk-sans
        noto-fonts-cjk-serif
        noto-fonts-emoji
      ] ++ (
        optionals cfg.nerdfonts (
          builtins.filter lib.attrsets.isDerivation (builtins.attrValues pkgs.nerd-fonts)
        )
      ) ++ cfg.extra;

      fontconfig.defaultFonts = {
        monospace = [ "CaskaydiaMono Nerd Font" ];
        sansSerif = [ "DejaVu Sans" "Noto Sans CJK JP" "Noto Sans" ];
        serif = [ "DejaVu Serif" "Noto Serif CJK JP" "Noto Serif" ];
      };
    };
  };
}